Useful macros for druids

Macros
General guides
Macros Beginners Guide Making a macro Macro conditionals Macro commands Category:Macros
Useful macros by class

At one time, there were some things that druids could not do without the aid of macros. Casting out-of-form abilities was one of these; whereas they used to be disabled, they now cause a character to change to the appropriate form (humanoid) and proceed to cast normally. This feature has made /cancelform lines unnecessary (except during flight).

Druids also have built-in Action Bar switches. There are 12 distinct Action Buttons for every form except Travel, Aquatic, and Flight. This eliminates the need for many macros based on form. Even so, druids, like warriors, can make use of the [stance] conditional. [form] is a synonym. See Making a macro: Conditionals and Stances for more information.

The role of the modern druid macro is to either 1) couple similar abilities and reduce the number of key presses needed to use everything, or 2) answer predictable situations with the best response. Be aware that these goals are in conflict with 'versatility', that is: as more commands are macroed, it becomes likely that a situation will arise that causes loss of control.

E.G., ( a macro that enters Bear Form if in-combat but Cat Form out-of-combat ) can lose mana and time when a player is ambushed.

Healing

Hover healing

/cast [target=mouseover,help,nodead][help][target=player] Healing Touch

Heal the character under the mouse pointer, or if there is no ally there, heal a friendly that you have targeted, or if there is none heal yourself. Replace Healing Touch with the spell of your choice.

Nature's Swiftness + Healing Touch - without global cooldown

/stopcasting
/cast Nature's Swiftness
/cast [target=player] Healing Touch

Omit [target=player] to heal your target instantly instead of yourself. Whatever spell you might be casting at the time you hit this button will be canceled and this emergency heal will be an instant one.

Healing Touch dispels Tree Form from its caster; if this is a concern, use Regrowth instead:

/cast [target=player, form:5] Regrowth; [target=player] Healing Touch

Another version of this macro could be:

/stopcasting
/cast [mod:alt,target=player][help] Nature's Swiftness
/castsequence [mod,target=player][help] reset=25/combat Healing Touch, Rejuvenation, Swiftmend, Regrowth

Here the emphasis is on healing a friendly target, but the player only when a modifier (ALT) is used. While Nature's Swiftness cools, Rejuvenation/Swiftmend and Regrowth serve as backup emergency heals.

Lifebloom / Rejuvenation rotation

#showtooltip Lifebloom
/castsequence [modifier:alt,target=player][target=mouseover, exists][] reset=7 Lifebloom, Rejuvenation, Lifebloom

Macro can be cast on mouseover target, target, or alt-self. This macro functions as a way to have one button for the heal rotation of Lifebloom/Rejuvenation. If you click it:

• 1st time: casts Lifebloom1
• 2nd time: casts Rejuvenation
• 3rd time: casts Lifebloom2
• (cast sequence resets)
• 4th time: casts Lifebloom3
• NOTE: If you wait 7 seconds the macro resets so you can start the process over again.

Rejuvenation and Swiftmend

#showtooltip Swiftmend
/castsequence [exists,help] reset=12/target Rejuvenation, Swiftmend
/stopmacro [exists,help]
/castsequence [modifier:alt,target=player][target=mouseover, exists][] reset=12 Rejuvenation, Swiftmend

Macro can be cast on mouseover target, target, or alt-self. Macro casts Rejuvenation on target, then when clicked again for same target will cast Swiftmend(If no cooldown).

Lifebloom on focus' target

#showtooltip Lifebloom
/focus [target=focus,exists,nodead] focus; [harm] target
/cast [target=focustarget] Lifebloom

This macro is useful for quickly reacting to raid damage on fights like Aran where the kill target randomly selects and damages members of a party. Just hit this macro each time you see the target of your focus change. If you don't have a focus at first, it will be set to your target.

Announcing Rebirth

#showtooltip
/stopmacro [nohelp,nodead]
/y Resurrecting %t
/cast Rebirth

This macro is useful when in a party or raid with more than 1 druid. It will announce the player who will receive your combat rez, so other druids know they don't need to rez anymore.

When the target has released, the spell will still work but you will yell "Resurrecting <no target>". For a variation that solves this problem, see: Useful_macros#Announce_resurrection_target

Healing against Anzu (epic Flight Form quest)

#showtooltip Rejuvenation
/target [modifier:shift] Eagle Spirit; [modifier:ctrl] Falcon Spirit; [modifier:alt] Hawk Spirit; party1
/cast [modifier] Rejuvenation (Rank 1); Rejuvenation
/targetlasttarget

This macro can temporarily replace your usual Rejuvenation macro against Anzu. Hold shift to target the Eagle Spirit, control for the Falcon, and alt for the Hawk. This will cause the macro to cast Rejuvenation rank 1. Without a modifier, it will target your party leader (usually the tank, to mark your opponents) and cast your max rank Rejuvenation.

Feral

Note: fixing your macros for 3.02: The names of some abilities have changed, i.e. "Mangle(Bear)" has changed to "Mangle - Bear".

Ravage & Shred 2-in-1

1. showtooltip

/cast [nostealth] Shred; [stealth] Ravage

Turns the hotkey to Ravage when Prowling & Shred when not Prowling.

Prowl action bar switch

#showtooltip Prowl
/cast [no combat, form:3] Prowl
/swapactionbar 1 2

You will however have to change your Pounce and other openers to the following macro to switch back:

#showtooltip Pounce
/cast [form:3, Stealth] Pounce
/ [Combat] swapactionbar 2 1

In the place of "Pounce" put your desired opener.

Mark + FFF

#showtooltip
/cast Faerie Fire (Feral) ()
/script SetRaidTarget("target",8)
/startattack

"/p Kill the skull!"

Taunt and start autoattack if it is off

/cast Growl
/startattack

Use this if you find yourself Growling and not auto attacking, losing the mob after the taunt wears off. Especially useful if you have enabled the option to turn auto attack off when you change targets.

Use item with attack ability

/use <item name>
/cast Mangle - Cat
/startattack

Pairing an activated effect with an ability that can use it is an excellent solution for those that want (a trinket's) benefits whenever the cooldown finishes. Obviously, the inherent drawback is the timing - but if you were going to forget about the item anyway, you gain on the average.

Cat opener / regular attack

/cast [nostealth][combat] Claw
/castsequence reset=6 Tiger's Fury, Ravage
/startattack [combat][nostealth]

or, putting Prowl in the same Action:

#showtooltip [stealth] Ravage; [nocombat] Prowl; Claw
/cast [combat] Claw
/castsequence [nostealth] Prowl; reset=6 Tiger's Fury, Ravage
/startattack [combat][nostealth]

This macro claws if you are unstealthed or in combat but still stealthed (to get you out quick). If you are in stealth but not in combat, then it casts Tiger's Fury on the first press, Ravage on the second press. The macro finishes by turning on your auto attack if you're not in stealth. The stop macro is in place so that you do not get unstealthed accidentally. Can be spammed out of stealth, but should be used a single press at a time when stealthed.

The macro suffers from a disadvantage - it makes it hard or problematic to get off a Ravage when you are low on Energy. Situations in which it may commonly be desirable to do so are:

1. in the middle of a PvP fight when you've just managed to get out of combat and gotten back into Prowl and have less than a second to get off a Ravage
2. in times when you grind quest mobs or just mobs in general with the mobs being in close proximity and not being difficult enough to warrant shifting out and re-healing yourself in between 'pulls' when you may wish to maximize time in combat as opposed to just minimize the time spent fighting each mob.

The macro does not provide a way to leave stealth. You could edit that into the macro, or just right-click the Prowl buff whenever you want to dismiss it.

When a Druid takes the Mangle talent, Claw is made obsolete by Mangle - Cat in every way.

Pounce / Shred, Claw, Rake, Rip finally

/castsequence [stealth]pounce;reset=25/combat/target shred, claw, claw, rake, rip, claw, claw

You may want to substitute Ferocious Bite for Rip when fighting lower level mobs, and Mangle for Claw if you have that ability. If you have mangle, substitute with:

/castsequence [stealth]pounce;reset=25/combat/target Mangle - Cat, shred, Mangle - Cat, rake, rip, Mangle - Cat, Mangle - Cat

Note that this macro does not take advantage of faster combo point generation from Primal Fury, and will also not account for misses, dodges, or parries.

Bear Form spammable attacks

/cast Maul
/castrandom Mangle - Bear, Mangle - Bear, Lacerate, Faerie Fire (Feral) ()

Why use Mangle twice? Mangle has a six second cooldown and should always be used when available. Lacerate, once it stacks to five, should only be used occasionally to keep the DOT up. Use this macro carefully; in a non-boss fight you won't be generating enough rage to get all these attacks off. Some people remove Faerie Fire and press it manually to ensure that the button does some damage with every press.

"Basic Bear Tanking Macro" from Karakye <Wrought from Ruin>'s Meatshield Guide:

#showtooltip
/castsequence reset=4 Mangle - Bear, Lacerate, Lacerate, Lacerate
/startattack

...will Mangle if the cooldown is up on it, if not do nothing. After Mangle's trigger of the 1.5 sec GCD, it will cast Lacerate up to 3 times as long as you hit the macro at least once every 4 seconds, then reset to Mangle again.

The reset time of 4 seconds was selected after much field testing. Change the reset number to 2, 3 or 4 and try it out on non-dangerous mobs to see what works for you. Also remember that you will tank multiple mobs, and spamming Swipe isn't always the answer to that, so you might need more control over which attack to use - Mangle, Lacerate, Swipe or Maul.

You may also wish to take off one Lacerate, so that the macro resets after just two Lacerates.

Druid's Shield Wall

#showtooltip
/run c="Druid's Shield Wall: 15 seconds of increased avoidance!"if UnitInRaid("player")then SendChatMessage(c, "RAID")elseif GetNumPartyMembers()>0 then SendChatMessage(c, "PARTY")end
/use Moroes' Lucky Pocket Watch
/use Badge of Tenacity

This macro warns your party or raid that you have activated the druid version of "Shield Wall" and then activates both your avoidance trinkets (Moroes' Lucky Pocket Watch and Badge of Tenacity). You must have both items equipped, of course. Since they don't share cooldowns and are instant, you can trigger them both at the same time. Thanks to the warning, your healer(s) will know they have to pay extra attention.

Shapeshift & Dash Combo

/cast [nostance:3] Cat Form; Dash

First push automatically shifts into Cat Form (unless you're already in Cat Form). Second push uses Dash. Good for chasing things down, etc.

Nuking

Root, DOT, debuff

/castsequence [outdoors] reset=target Entangling Roots, Moonfire, Starfire; Moonfire, Starfire

Moonfire has a slight chance to break Entangling Roots. The order of the two could be reversed, but this gives the mob time to Charge, cause spell pushback, or worse, prevent a life-saving spell. Despite these risks, this is a powerful Balance opener:

/castsequence [outdoors] reset=target Starfire, Moonfire, Entangling Roots, Insect Swarm; Starfire, Moonfire, Insect Swarm

Barkskin + Hurricane

/stopcasting
/castsequence reset=60/combat Barkskin, Hurricane

Totem destroy

/targetexact Wrath of Air Totem
/targetexact Mana Spring Totem
/targetexact Poison Cleansing Totem
/targetexact Windfury Totem V
/targetexact Mana Tide Totem
/targetexact Grounding Totem
/cast Moonfire(Rank 1)

Maim / Lacerate / Healing Touch rank 4

#showtooltip
/cast [form:1] Lacerate; [form:3] Maim; [noform] Healing Touch(rank 4)

This will give you one button that in bear form does [Lacerate]; in cat it does [Maim], and in caster it does a downranked Healing Touch. The button will show the icon for whichever skill/spell is up.

This is an example that is made obsolete by Action Bar switching. It remains practical for custom User Interfaces that make all 120 Action Buttons visible simultaneously. Also, since there are only 12 Action Buttons reserved per form, a 13th action may need to be a macro.

Faerie Fire appropriate to form

/cast [form:1/3] Faerie Fire (Feral)(); Faerie Fire

Bears and cats cast a "Feral" Faerie Fire. Other forms cast the regular type. All of the parentheses (()) that you see are needed; without them, "Feral" is mistaken as the spell rank, and the cast fails. An empty pair of brackets says: use the highest rank available.

Healing spell / damage spell

/cast [modifier:alt, target=player][help] Rejuvenation; [harm] Moonfire

Holding ALT will cast Rejuvenation on yourself regardless of who you're targeting; otherwise cast Moonfire on a harmable target and Rejuvenation on a healable one.

This behavior can also be accomplished using two Action Buttons, key bindings, and spells alone - with one exception: If Rejuvenation is cast without a macro, and nothing is targeted, then the cursor will await identification of a target (the next unit you click).

Cast innervate on yourself without changing target

/cast [target=player] Innervate

Note that the `target=player' bit is not an instruction to change the target to yourself. Rather, it specifies the spell-target for the spell to follow (here the innervate), which is totally different from your `current' target. Viz, your `current' target won't be changed when this macro is used. If a target-change was to take place, and you were to damage another target by accident, you would lose any combo-points you had stacked.

Keep Rooted / Hibernated

/focus [target=focus, exists, nodead] focus; [btn:2][] target
/cast [target=focus] Entangling Roots

This is a great crowd control ability either in pve or pvp against rogues and warriors. First you root the enemy that you want to save for later, then whenever it's time to re-tangle, just press the key again without changing targets.

See also: http://www.wowwiki.com/Useful_macros#Crowd_Control_stays_on_1_mob

Buffing

/castsequence reset=target Mark of the Wild, Thorns

This will cast MOTW and then Thorns on your target.

A play on this macro for feral druids self-buff is:

/castsequence [target=player] reset=10 Thorns, Mark of the Wild

The one below is a little more involved, but easy to use.

• Using the left mouse button will buff your current target with MotW, then Thorns if pressed a second time. If you hold shift, it will rebuff your target with Thorns.
• Using the right mouse button will buff yourself with MotW, then Thorns on the second press. Shift + right clicking will rebuff yourself with Thorns.
• Since Thorns wears off faster than MotW, it is nice to have a way to rebuff without having to cycle through MotW first. The shift modifier was added to address this. Why not cast Thorns first, then? Not everyone in the party should get Thorns cast on them when in a group.
• The cast sequence will reset after 6 seconds for self-buffing and after changing targets for target buffing.

/cast [modifier:shift, button:2, target=player] Thorns
/castsequence [button:2, target=player] reset=6 Mark of the Wild, Thorns
/cast [modifier:shift] Thorns
/castsequence reset=target Mark of the Wild, Thorns

Here is a version with better control. If you click it with the middle button of the mouse it casts Gift of the Wild, if you click with right button it casts Thorns, if you activate it in some other way it casts Mark of the Wild:

#show Gift of the Wild
/cast [button:3] Gift of the Wild; [button:2] Thorns; Mark of the Wild

Buffmacro for control-freaks:

#showtooltip
/cast [modifier:shift] Thorns; [modifier:alt] Gift of the Wild; Mark of the Wild

All-terrain best form

#showtooltip
/cancelform
/dismount
/cast [modifier: Alt] Swift Spectral Tiger; [swimming] Aquatic Form; [flyable,nocombat] Swift Flight Form; Travel Form

The form that your druid will take is determined by these checks, in this order:

• Swimming? Become a sea-lion. (Shift out if already a sea-lion.)
• Able to fly? Become a bird. (Shift out if already a bird.)
• Able to mount? Mount up. (You may only mount if you are standing still, outside, and out of combat.)
• If nothing else occurs: become a cheetah or panther. (If in PvP combat, powershift.)

Replace "Swift Flight Form" with plain "Flight Form", or "Swift Spectral Tiger" with the name of your land mount.

Equip  [Charm of Swift Flight] when using [Swift Flight Form]

/equip [flying] {your normal trinket}
/equip [nostance] Charm of Swift Flight
/cast Swift Flight Form

But wait! It is perhaps not in your best interest to use a macro to manage your flight gear. See Useful_macros#Equip_Riding_Crop_.2F_pre-BC_riding_equipment to see why.

Equip the best weapon and off-hand per form

#showtooltip Dire Bear Form
/equip [stance:1/3] Epoch-Mender
/equip [stance:1/3] Idol of the Emerald Queen
/cast [nostance] Dire Bear Form
/cancelform
/equip [nostance] Earthwarden
/equip [nostance] Idol of Brutality

(To use this for Cat Form, just replace Dire Bear Form with Cat Form.)

This macro will cancel form and equip your healing weapon/idol so you can heal yourself. Then, when you use it again to return to feral form, it will equip your DPS or tanking weapon and idol.

See also: http://www.wowwiki.com/Useful_macros#Easy_equip_off-hand

Tracking and gathering

/castsequence [nocombat, form:3] reset=combat Track Humanoids, Find Herbs, Find Minerals
/castsequence [nocombat, noform:3] Find Minerals, Find Herbs

The Druid has one tracking ability that can be selected: this can, however, put a dint in your gathering prospects, and only be cast in cat form.

"form:3" checks can remove the track humanoid when not in cat form. "reset=combat" changes it so that after a combat, it automatically goes back to track humanoids first, no matter what was previously cast (so you can see if any others are around).

Nature's Grasp and follow

#showtooltip Nature's Grasp
/cast Nature's Grasp
/follow

In the laziness department, people who use the /follow command to go afk in a wide variety of in-game activities (Molten Core runs, AV, corpse-runs) are generally recognized to be a step above. If you'd like to join this elite but misunderstood crowd, and cut down on your UI clutter at the same time, install this someplace convenient.

See also: Useful_macros#Follow_with_emote

Shadowmeld from Prowl (Night Elf only)

#showtooltip
/cast [form:2,stealth][nonform:2]Shadowmeld; Prowl

You may be in a situation where you wish to position yourself with Cat Stealth, then remain invisible while becoming humanoid. That's what this macro does. If used at any other time, it will enter the stealth appropriate to the form.

There is no way to switch immediately to Prowl from Shadowmeld, but you can do so in 1.5 seconds by using: Cat Form -> this macro.

Feral Charge Focus Target

/cancelaura [stance:2] Aquatic Form; [stance:3] Cat Form; [stance:4] Travel Form; [stance:5] <Moonkin Form/Tree of Life>; [mounted] <Mount Name>
/focus [target=focus,noexists]
/cast [nostance] Dire Bear Form
/cast [target=focus] Feral Charge

Will need to bash the key till' the Feral Charge goes off, due to the server side delay on Furor. Works great in arenas :). A side note after you have made the Feral Charge you will remain in Bear Form so keep that in mind.

External links

The Druid forums at the Blizzard official web site have an excellent thread (continued here and here) full of macros for many more situations. Feel free to browse and bump for a sticky.