Useful macros

Macros
General guides
Macros Beginners Guide Making a macro Macro conditionals Macro commands Category:Macros
Useful macros by class

For more info on the new macro syntax introduced in patch 2.0, see HOWTO: Make a Macro

Attack

/startattack
/cast [nocombat] attack

This will act like a normal Attack button, except that it won't toggle autoattack off in combat (hit escape if you need to do that). Best when combined with the icon, so it'll display your current weapon. As of patch 2.1.0, this macro now requires the /cast command in order for the icon to function correctly.

Mount

Mount Outside

/use [nomounted,outdoors] Whistle of the Black War Raptor

This will attempt to mount if you are outside and not mounted.

Random Mount

/userandom [nomounted,nocombat] <mount 1>, <mount 2>, <mount 3>
/dismount

This will randomly use one of the mounts listed in the macro if you are not mounted and not in combat, if you are mounted it will dismount you, otherwise it does nothing. This won't work for Paladins and Warlock's Summon Charger/Dreadsteed, but substituting /userandom with /castrandom does work, as follows.

Random Flying Mount

/dismount [mounted]
/stopmacro [mounted]
/castrandom [nomodifier:ctrl] <mount 1>, <mount 2>, etc ...
/castrandom [modifier:ctrl] <flying mount 1>, <flying mount 2>, etc ...

This is like the random mount macros above, but will choose a random flying mount if Ctrl is held down when it is clicked otherwise it will randomly pick a non-flying mount.

Mount / Hearthstone

#showtooltip hearthstone
/use [button:2, nomounted] Hearthstone
/dismount [mounted]
/use [button:1, nomounted, nomodifier:alt] Tawny Windrider
/use [button:1, nomounted, modifier:alt] Red Skeletal Warhorse

This one will make you ride your normal mount on the main land, ride your flying mount in outland, and hearthstone on rightclick. If you alt+click it, it'll summon your normal mount wherever you are. Downside is that is always gives an error message on screen. There is no easy way around this. The icon and tooltip will show your cooldown of your hearthstone. If you put the icon on the Questionmark icon, it'll also show the hearthstone icon.

And here is the shortened version of the above:

#showtooltip
/use [button:2,nomounted] Hearthstone
/stopmacro [flying]
/dismount [mounted]
/use [button:1,flyable,nomodifier:alt] Blue Windrider; [button:1,modifier:alt] Great White Kodo;

Flying/Ground Mount no Error Message

/cast [outdoors,nomounted,nomodifier:ctrl,flyable] Snowy Gryphon; [outdoors,nomounted] Black War Ram
/dismount [mounted]

This will use your flying mount in Outland, and your normal mount in Azeroth. If you hold ctrl, it will use your normal mount no matter where you are. It will not attempt to mount you if you are in an area where you cannot mount, and will not give any error messages.

This macro also leaves plenty of room for class-based additions.

No Dismount Flying

/stopmacro [flying]
/dismount [mounted]
/use [outdoors,nomounted,flyable] Golden Gryphon
/use [outdoors,nomounted] Stormpike Battle Charger

This is similar to the above, except it prevents a dismount from occurring if you're in the air.

Equip Riding Crop

#showtooltip Snowy Gryphon;
/equip [mounted] Xi'ri's Gift;
/dismount [mounted];
/equip [nomounted] Riding Crop;
/use [nomodifier, nomounted]Snowy Gryphon;
/use [modifier:alt]Palomino Bridle;

This is a very handy macro that will do a plethora of mount-related things. First, if just clicked (or hotkey is used) it will summon your flying mount (change Snowy Gryphon to your particular flying mount type). If its alt-clicked (or alt+hotkey is pressed) it will summon your ground mount (change Palomino Bridle to your particular ground mount type). Also, any time you use it and are not mounted it will first equip your riding crop (can be changed to use Carrot on a Stick if you desire) and then continue to use the selected mount. If you are already mounted it will dismount and equip your original trinket (replace Xi'ri's Gift with whatever trinket you normally have in the top trinket slot). In addition this macro avoids all error messages from appearing on the screen. You can also edit the first line to have it show the tooltip of whichever mount you prefer, or leave it out if you dont want any tooltip displayed. If you select the ? icon when you create this macro it will display the picture for your original trinket, so I would suggest selecting a picture that represents your mount from the possible choices when creating.

Equip Riding Crop/Trinket Flying/Ground

/use [nomounted, outdoors] <Flying Mount>
/use [nomounted, outdoors] <Ground Mount>
/equip [nomounted, outdoors] Riding Crop
/equip [mounted] <Trinket>
/equip [indoors] <Trinket>
/dismount [mounted]

This macro will use the appropriate mount depending on if you're in outland or azeroth. When mounting up, it will equip your riding crop, and when dismounting it will equip your <trinket>. If the mounting is interrupted this will not work correctly. It also has an extra clause to equip your <trinket> if you use it indoors. This is useful if you walk indoors and forget to hit your macro to dismount (in other words, you were dismounted automatically for being indoors). You can tap this macro again and it will equip your trinket for you. The macro will display an error each time you try to mount however ("You can't use that here" in Azeroth, and "Another action is in progress" in Outland). This appears to be unavoidable, since the macro is basically using both and allowing the WoW error handling to pick the correct one. I would recommend using the UIErrorsFrame bit mentioned two code sections above, but that exceeds the maximum number of characters allowed. Just make sure to replace <...> with your respective equipment. For pallys and warlocks, to summon thier ground mounts replace /use [nomounted, outdoors] <Ground Mount> with /cast [nomounted, outdoors] <Mount spell>

Variation

/use [nomounted, nomodifier:ctrl] <Flying Mount>
/use [nomounted] Red Skeletal Warhorse
/equip [nomounted, outdoors, nocombat, nomodifier:shift] Riding Crop
/equip [mounted] [indoors] [combat] <Trinket>
/dismount [mounted, noflying]

This is a variation of the above macro that I came up with. It has similar funcitons in that it will choose the flying mount or regular mount based on what can by used, equips the riding crop and reequips your other trinket on dismount. I added the [combat] condition for reequipping the original trinket in case you are forced off your mount or interrupted while mounting. Also, you can hold down shift to override the riding crop, in case you want to mount, but don't want to trigger the 30 second trinket cooldown for your original trinket when you dismount, like in a battleground. Finally, this macro will also not dismount you while flying.

Enable Gathering

/cast [nomounted] <mount>
/cast [mounted] Find Herbs
/dismount

This macro will assist in turning on your gathering professions when you dismount. This is near-automation of turning on a tracking ability. Note: Miners just replace "Find Herbs" with "Find Minerals". (Suggestion: Hunters may want to try this for tracking purposes also)

Flying Mount if Target Exists

/cast [target=mouseover,exists] standard mount; flying mount

If you have no target under your cursor you will use normal mount. Have a target under mouse (your unitframe for instance) and you will fly (for this to work you must have your mount assigned to a key).

No Dismount While Flying

#showtooltip
/use [button:2] <flying mount>
/console autoDismount 0
/stopmacro [button:2]
/use <ground mount>
/console autoDismount 1 

With Patch 2.1.0, Blizzard introduced the ability to automatically dismount in the event that you cast a spell. While this is good while using your ground mount, this is dangerously bad for most classes when using your flying mount. While there is a toggle for this in your Interface Options, the above macro will enable autodismount when using your ground mount and disable autodismount when using your flying mount.

Bandage

Heavy Netherweave Bandage on Self

This macro will always use Heavy Netherweave Bandages on yourself, regardless of target.

/use [target=player] Heavy Netherweave Bandage

Target Specific Modfier Key

/use [modifier:alt,target=player] Heavy Runecloth Bandage
/use [modifier:ctrl,target=pet] Heavy Runecloth Bandage
/use [help] Heavy Runecloth Bandage

1. If you Click the macro while holding down the ALT key, you will bandage yourself.
2. If you Click the macro while holding down the CTRL key, you will bandage your pet.
3. If you Click the macro by it self, you will bandage a friendly target.

Heavy Netherweave Bandage Friendly then Self

/use [help,nomodifier:alt] Heavy Runecloth Bandage; [target=player] Heavy Runecloth Bandage

This macro will use a Heavy Runecloth Bandage on your target if you can, yourself otherwise. Unless you hold down ALT, in which case you will always bandage yourself.

Use either Trinket

This macro activates the upper trinket if it is not on cooldown. If it is on cooldown, the macro tries to activate the lower trinket. This is useful if you have two trinkets on short cooldowns that do similar things (add attack power, add spell damage, add healing, etc.). You will get an error that one item is not ready every time you use this macro.

/use 13
/use 14

Racial Abilities

Blood elf

One key [Arcane Torrent] and [Mana Tap]

This macro will bind [Arcane Torrent] and [Mana Tap] to one key.

/cast [modifier] Arcane Torrent; Mana Tap

[Mana Tap] -> [Arcane Torrent]

This macro will cast [Mana Tap] the first time you use it, and [Arcane Torrent] the second time you use it. It will reset itself every time that [Mana Tap] is ready. If you use the ? icon for the macro, it will appear as the next skill in the cast sequence.

#showtooltip
/castsequence reset=30 Mana Tap, Arcane Torrent

[Mana Tap] / [Arcane Torrent]

This macro is my personal variation on the one above. I didn't like that I couldn't use Arcane Torrent if my target couldn't be mana tapped, so I made this macro. It's main additional feature is that the cast sequence only goes if you have a target, otherwise it will simply use Arcane Torrent. This is mostly to catch a rogue that just stealthed or vanished near you, although you could quickly deselect your target if you needed to use Arcane Torrent.

#showtooltip
/castsequence [target=target,exists] reset=30 Mana Tap, Arcane Torrent
/cast Arcane Torrent

Gathering Toggle

/castsequence [nocombat] find herbs, find minerals

Simple macro now that changes between [Find Herbs], [Find Minerals] - bind it to a mouse key and you can change it every few second or so as you run along.

For hunters, warlocks, druids and paladins it is easy to add in the other tracks, or make your own. Simply substitue for one of the finds below, or add on to the end, seperated only by a comma. I have included some examples here.

The [nocombat] check in the macros is so you don't accidentally trigger a global cooldown in combat.

Follow with Emote

/script if UnitIsPlayer("target") and UnitIsFriend("player","target") and CheckInteractDistance("target",4) then FollowUnit("target") SendChatMessage("is following "..UnitName("target")..".","EMOTE") end

The use of this macro is the equivalent to following a unit, and typing "/me is following %T."

If your target is not a friendly player within following range, it does nothing.

Fishing

/equip [noequipped:Fishing Pole, nomodifier:alt] Seth's Graphite Fishing Pole;
/equip [modifier:alt] Mana Wrath;
/equip [modifier:alt] Lamp of Peaceful Radiance;
/cast [equipped:Fishing Pole, nomodifier:alt] Fishing;

This macro is handy in that on a regular click (or hotkey press) it will equip your fishing pole (simply change Seth's Graphite Fishing Pole to the name of whichever pole you use), and when pressed again will begin fishing. On an alt-click (or alt+hotkey) it will re-equip your normal weapon(s). If you use a two hand weapon, simply take out the third line and change Mana Wrath to your own main weapon, otherwise if you use two change Mana Wrath and Lamp of Peaceful Radiance to your own particular weapons. This macro also avoids any error messages from popping up. You could also add to this macro to have it swap out a Lucky Fishing Hat or gloves with the fishing enchant as well, if you had them.

Battleground

/yell "%n, stop running so I can heal you!"

This is a simple macro for a healer in a battleground. Often your heal targets will be running away from battle, so you must tell them to stop running.

Battle map

/script BattlefieldMinimap_LoadUI();
/script if( BattlefieldMinimap:IsVisible() ) 
then MiniMapBattlefieldFrame.status = ""; BattlefieldMinimap:Hide(); 
else MiniMapBattlefieldFrame.status = "active"; BattlefieldMinimap:Show(); end

This macro will toggle the battle map in every region, just like in the battlegrounds and the areas with outdoor pvp.